.title	GoMeet

	.inclu	"B:GLOBAL"
	
	sect	code

oGoMet:
	bic	#UtmOn, KSW		; Cancel output to file (if on)
	Repars	#2, #Whmeet		; Which meeting?
	bcc	3$			; Just CR
	jmp	998$
3$:	mov	#2, r0
	call	fixlst
	bcc	5$
	jmp	999$
5$:	mov	found(r0), r1		; R2 points to meeting in memory
	call	GetAdr			; Not a beautiful solution, but...
	mov	r1, r2

	clr	STKEND+4
	br	7$

; at entry R2 points to list entry

	ogome =	.		; OBS! OBS! OBS!

				; STKEND, # of unread text in this meeting
				; STKEND+2, # of texts in this meeting
				; STKEND+6, nodrec
				; STKEND+10, nodpos

	mov	#1, STKEND+4
7$:	tst	r2
	bne	8$
	jmp	999$

8$:	mov	#PrsPro, r1
	mov	#6., r0
9$:	mov	(r2)+, (r1)+		; Save part of command
	sob	r0, 9$
	mov	#PrsPro, r2
888$:	Gos	GetMe <#FB1>
	mov	24(r1), r4		; Any memberships?	
	mov	26(r1), r3		; Membership pointer (in file 1)

10$:	tst	r4
 	beq	100$
	mov	r3, STKEND+6		; recnum
	Gos	TryRec <#1, r3, #FB1, #Unlock>
	mov	r1, STKEND+10		; recpos (1'st byte)
	mov	2(r1), r3		; Next mebership to r3
	add	#10, r1
	mov	#20., r0
	sub	r0, r4
	bhis	20$
	add	r4, r0
	
20$:;	tst	(r1)
;	bne	21$			; I was not a member...
;	jmp	bug$
21$:	cmp	(r1)+, (r2)
	beq	150$			; To 150$ if I was a member
	cmp	(r1)+, (r1)+
	sob	r0, 20$
	tst	r3			; Next MEDLEMSSKAP (I hope)
	bne	10$

100$:	write	#Nomemb
	Gos	GetRec <#1, rArg(r2), #FB2, #Unlock>
	bit	#xOPN, 16(r1)
	bne	105$
;	mov	#1, r0
;	call	Releas
	mov	10(r1), r0		; Save the organisator
	write	#Closed			;  This destroys r1!
	tst	r0			; Is there an Organisator?
	bne	103$			; Oh yes! to 103$
	gos	Get <#1, #2, #FB3, #1, #Unlock>
	mov	FB3+46, r0		; Get 'KOM-responsable'
	bne	177$

	jmp	997$
177$:	
	call	PrtNam
	jmp	997$	

103$:	call	PrtNam
	write	#TheOrg
	jmp	997$

105$:	call	PCRLF
	Parser	#JANEJL, #1, #U.Go.P
	call	PCR2LF
	tst	Level
	beq	110$			; Just CR means "Yes"
	mov	Found, r1
	call	GetAdr
	tst	(r1)
	bne	110$
	jmp	998$

110$:	mov	@#Me, r0		; Add ME to the meeting
	mov	rArg(r2), r1
	Call	AddMem
	jmp	888$

150$:	mov	(r1), STKEND+12
	mov	2(r1), STKEND+14
	mov	(r2), r0
	call	saveit
	gos	CrTeLs <r0, (r1), 2(r1)>
	mov	r0, r3
;	bne	152$
;	cmp	CurGrp, (r2)
;	bne	152$
;	clr	CurGrp
152$:	sub	STKEND+10, r1
	sub	#2, r1
	mov	r1, STKEND+10

155$:	call	MtxBgn

	gos	GetRec <#1, rArg(r2), #FB2, #lock>
	mov	rHigh(r2), STKEND	; HIGH
	mov	r3, STKEND+2

	.date
	mov	@#xrb, 36(r1)
	mov	@#xrb+2, 40(r1)		; Get date last present.
	tst	10(r1)			; Any Organizer?
	bne	157$			; Oui!
	mov	Me, r0
	mov	r0, 10(r1)		; Save me as Organizer.
	push	r1
	write	#U.gt.O
	pop	r1			; 
	inc	STKEND+4		; 
	br	158$

157$:	mov	10(r1), r0

158$:	gos	put <#1, ,#FB2>		; Update meeting.

	call	MtxEnd

	tst	20(r1)			; See if there is a presentation
	bne	160$
	tst	22(r1)
	beq	165$
160$:	inc	STKEND+4		; Indicate that we dont want any 
					;  presentation
165$:	mov	(r2), r1		; R2 points to meeting #
	call	GoToIt
	bit	#xBL, @#MyFlag		; Bar line?
	beq	170$
	push	r0
	mov	#68., r0
	mov	#'=, r1
	Call	String
	pop	r0
	call	PCRLF

170$:	write	#Meetis
	mov	(r2), r0
	call	PrtNam
	call	PCR2LF
.if df aupres
	tst	STKEND+4
	bne	175$
	cmp	r0, Me			; Suis-Je organisateur?
	bne	175$
	mov	(r2), r0
	write	#ppleas
	call	MkPres
	call	PCRLF
.endc
175$:	write	#U.have
	mov	STKEND+2, r1
	clr	r0
	call	Deco16
	Write	#Unseen
	cmp	STKEND+2, #1
	beq	180$
	mov	#'a, r0
	call	ttyout			; Pluralize 

180$:	write	#TxtsOf
	mov	STKEND, r1
	clr	r0
	call	deco16
	Write	#Total	
997$:	call	PCRLF
998$:	call	PCRLF
999$:	rts	pc

;bug$:	write	#bugout
;	movb	#186., firqb
;	call	error

;+	Goes to a meeting. 
; Data passed:  r0 = ORGANISAT\R (or 0)
;		r1 = Meeting (or 0)
;-
oGToIt:
	push	<r0, r1>
	cmp	r1, thsgr		; In this meeting already?
	beq	100$
;	cmp	r1, curgrp
;	bne	100$

	bit	#AbsPrv!AdmPrv, KSW
	bne	10$
	mov	#UnProm, Stat
	tst	r1
	beq	10$
	cmp	Me, r0
	bne	10$
	mov	#ppromp, Stat

10$:	mov	r1, thsgr
	mov	STKEND+6, nodrec
	mov	STKEND+10, nodpos
	mov	STKEND+12, texrea
	mov	STKEND+14, startr

	mov	#PreLst, r1
	call	GetAdr
	mov	Job, r0
	asl	r0
	asl	r0
	asl	r0
	add	r1, r0
	tst	(r0)+			; N{rvarolista.
	mov	thsgr, (r0)
100$:	pop	<r1, r0>
	rts	pc
	
saveit:
	tst	curgrp
	beq	10$
	cmp	(r2), curgrp
	beq	10$
	call	savem
10$:	rts	pc


;Text	bugout,	<"Yeach A BUG!!"<cr><lf>>
Text	Meetis,	<"M|tet heter: ">
Text	Whmeet,	<"Vilket m|te vill du G] till?">
Text	NoMemb,	<"Du {r inte med i detta m|te."<CR><LF>>
Text	U.Go.P,	<"Vill du g} med i detta m|te  <Ja>">
Text	Unseen,	<" ol{st">
Text	TxtsOf,	<" inl{gg av ">
Text	Total,	<" inl{gg totalt.">
Text	Closed,	<"M|tet {r slutet."<cr><lf>"F|r medlemsskap kontakta ">
Text	TheOrg,	<" (m|tets organisat|r)">
Text	An.Adm,	<"n}gon administrat|r.">
.if df aupres				; Automagic presentation
Text	ppleas,	<"Nu skall du skriva en presentation av detta m|te!"<cr><lf>>
.endc
U.gt.O:	.byte	20$-10$
10$:	.ascii	"Du har |vertagit organisat|rsskapet f|r detta m|te."<cr><lf>
	.ascii	<lf>
20$:
	.even

	.end