.title	letter			

	.inclu	"B:GLOBAL"

	sect	code


READi:
	clr	tmp
	cmp	found, defcmd
	beq	READit
	call	skicom
	tst	lstlft
	beq	50$
	br	READit

50$:	rts	pc

READcc:	mov	#1, tmp
	cmp	found, defcmd
	beq	READit
	clr	tmp

READit:	tst	Thsgr			; Any current meeting?
	bne	10$			; Yes.
	write	#NGM			; No. Complain & exit!
	rts	pc

10$:	cmp	thsgr, curgrp		; Any non read entries?
	bne	15$			; No.
	tst	lstlft
	bne	30$
15$:	write	#notex			; Complain & exit!
	rts	pc

20$:	tst	lstlft
	bne	30$
	write	#inlutp
	rts	pc

30$:	mov	@lstptr, r2
	add	#2, lstptr
	dec	lstlft
	inc	texrea

	gos	getrec <#2, r2, #FB2, #unlock>
	mov	#FB2, curblk
	mov	r1, r4

	cmp	(r1)+, #1		; Type of node.
	bne	20$
	cmp	(r1)+, higlim
	bhi	20$
	cmp	(r1), higlim+2
	bhi	20$

	mov	(r1), ltxtre+2		; Text # for last read text.
	mov	-(r1), ltxtre
	tst	tmp			; Are we dealing with a comment?
	bne	40$			; Yes!
	mov	(r1)+, lnctre		; Text # for last non comment text.
	mov	(r1), lnctre+2
	
40$:	mov	r4, r1
	mov	show, r0
	mov	r2, oldl
	call	dsply2

	tst	lstlft
	bne	100$

	gos	crtels <,,>

	tst	lstlft
	bne	100$
	mov	hignum, texrea

100$:	rts	pc


READl:	tst	unrel
	beq	400$

10$:	mov	@unrel, r1
	beq	400$
	cmp	#-1, r1
	bne	100$

	push	#10$

20$:	add	#2, unrel
	mov	@unrel, mypoin
	add	#2, unrel
	rts	pc

100$:	add	#2, unrel
	cmp	#-1, @unrel
	bne	200$
	call	20$

200$:	inc	myread
	mov	r1, OldL
	mov	#FB4, CurBlk

	call	MtxBgn

	gos	GetRec,	<#2, r1, CurBlk,>
	.date
	mov	xrb, 44(r1)
	mov	xrb+2, 46(r1)
	gos	Put,	<#2,, CurBlk>

	call	MtxEnd

	mov	show, r0
	jmp	dsply2

400$:	write	#NOL
	rts	pc

	sect	texts,d

	.even

Text	notex,	<"Du har inga ol{sta inl{gg i detta m|te"<cr><lf><lf>>
Text	NOL,	<"Du har inga ol{sta brev"<15><12><12>>
Text	inlutp,	<"Texten {r raderad."<cr><lf>>
Text	NGM,	<"Du m}ste g} till ett m|te f|rst."<15><12><12>>

	.even

	.end