.title	who			; WHO IS IT?

	.inclu	"b:global"

	Text	VVDBS,	<"Vem vill du B\RJA som">
	Text	whop,	<"Vad heter du">
	Text	pasw,	<"Ange ditt l|senord - ">
	Text	thanks,	<"Tack!"<cr><lf><lf>>
	Text	missit,	<"L|senordet st{mde inte - Ange nytt namn!"<lf>>
	Text	nowp,	<"Nu skall du ange ett personligt l|senord!"<cr><lf>>
	Text	ilpw,	<"Otill}tet l|senord."<cr><lf><lf>>
NowPre:	.byte	20$-10$
10$:	.ascii	"Nu ska du skriva en presentation om dig sj{lv."<cr><lf>
20$:

	sect	code

who:	tst	me
	beq	askme
	call	save

	RePars	#2, #VVDBS
	bcs	10$
	call	fixlst
	bcc	cont
10$:	rts	pc

ask:	write	#CRLF
askme:	parser	#GRPLST, #1, #whop
	write	#CR2LF
	tst	level
	bne	10$
5$:	call	ReLink
	br	askme

10$:	clr	r0
	call	fixlst
	bcs	5$
cont:	mov	found(r0), r1
	call	GETADR
	mov	r1, r0
	mov	rArg(r0), r1
	mov	rHigh(r0), tmp+10
	push	r1
	gos 	getrec	<#1, r1, #FB1, #lock>
	push	<r1, r0>

	mov	6(r1), r0
	add	#62, r1
	push	<r1, r0>
	mov	#6, r2
3$:	cmpb	(r1)+, #'?
	bne	5$
	sob	r2, 3$

	write	#nowp
	mov	#paswp1, r0
	call	askpw
	pop	r0
	call	krypt
	bcs	46$
	mov	#6, r0
	pop	r1
	mov	#tmpstr+1, r2
44$:	movb	(r2)+, (r1)+
	sob	r0, 44$
	pop	r0
	gos	put	<#1, r0, #FB1>
	write	#CRLF
	br	21$

46$:	pop	<r0, r0, r0, r0>
	write	#ilpw
	tst	me
	beq	ask
	jmp	rt

5$:	mov	#1, r0
	call	release
	bit	#ABSPRV, KSW
	bne	19$
	write	#pasw
	call	readln
	pop	r0
	call	krypt
	pop	r4
	pop	r0
	mov	#tmpstr+1, r3
	movb	tmpstr, r2
10$:	cmpb	(r4)+, (r3)+
	bne	15$
	sob	r2, 10$
	br	20$

15$:	pop	<r0, r0>
	tst	me
	bne	16$
	mov	#2, xrb
	.sleep
	write	#missit
	call	CATA
	jmp	ask

16$:	write	#missit
	write	#CRLF
	jmp	rt


19$:	pop	<r0, r0, r0>
20$:	write	#thanks
21$:	mov	(sp), r0
	mov	114(r0), r0		; Default terminal typ.
	beq	25$
	mov	#GRPLST, r1
	call	FindCm
	tst	r0
	beq	25$
	mov	r0, r1
	sub	#rStr, r1
	call	MovTTD
25$:	pop	r0
	mov	(sp)+, myrec
	mov	6(r0), me
	mov	16(r0), myflag
;	mov	26(r0), myinlp
	mov	36(r0), mypriv
	mov	102(r0), myread
	mov	104(r0), mypoin
	mov	tmp+10, myhigh		; HIGH.
	mov	#1, prspri
	cmpb	#xSuU, mypriv
	bhi	40$
	beq	30$
	bis	#4, prspri
30$:	bis	#2, prspri
40$:
	clr	thisgp
	clr	thisg
	clr	thisl
	clr	oldl
	clr	UNREL
	clr	myclet
	clr	mycinl
	clr	curjoi
	dec	curjoi
	clr	Show
	clr	r1
	bis	20(r0), r1
	bis	22(r0), r1
	bne	4711$
	cmp	112(r0), #10.		; Time to make a presentation?
	blo	4711$
	write	#NowPre
	mov	me, r0
	call	Mkpres			; Make presentation.
4711$:	mov	#poole, r1
	mov	#<mypptr-poole>/2, r0
4713$:	clr	(r1)+
	sob	r0, 4713$	
	mov	#poole, @#mypptr

	mov	#PreLst, r1
	call	GetAdr
	mov	job, r0
	asl	r0
	asl	r0
	add	r0, r1
	mov	me, (r1)+
	clr	(r1)
	clr	KSW

	bit	#xANW, MyFlag
	beq	9119$
	call	SNews
9119$:	mov	#unprom, stat
	cmp	myread, myhigh
	bhis	rt
	jmp	fixlet			; CALLR FIXLET.

rt:	rts	pc


	.end