.title	Presentation

	.inclu	"b:global"

	sect	code


;+ Make presentation.
; Data passed:	 r0, Group to present.
; Data returned: C set if something went wrong.
; All file buffers are destroyed.
;-
oMkPrs:	
	push	<r1, r2, r3, r4, r0>
	mov	#GrPLst, r1
	call	FindCm
	mov	r0, r4			; Unperson?
	bne	5$
	jmp	900$				; 
5$:	mov	#FB3, r2
	gos	get <#1, #2, r2, #1, #Unlock>
	add	#10, r2
	cmp	rPri1-rStr(r0), #2	; Meeting
	bne	10$
	tst	(r2)+
10$:	tst	(r2)
	bne	20$
	write	#NopMet
	br	900$
	
20$:	push	(r2)
	mov	#PresOf, r0		; Move the header string.
	movb	(r0)+, r3
	mov	r3, r2
	mov	#TmpStr+1, r1
30$:	movb	(r0)+, (r1)+
	sob	r3, 30$
	mov	r4, r0			; This is the address of the person
	movb	(r0)+, r3
	add	r3, r2
40$:	movb	(r0)+, (r1)+
	sob	r3, 40$
	movb	r2, TmpStr
	
	mov	#-1, @#Line
	mov	rArg-rStr(r4),-(sp)
	call	compos
	pop	<r4,r2>
	tst	r0
	beq	900$

	mov	#-1, @#Line
	push	MaxLin			; Maklet is very found of destroying
					;    this variable (Caused by a bug)
	gos	MakLet <Me, r2, #10,,,>
	call	Putlet
	pop	MaxLin			; This ought to fix it! (temporary)
	push	<r0, r1>
	write	#sento1
	mov	sp, r1
	clr	r0
	call	deco32
	write	#sento2
	mov	r2, r0
	call	prtnam
	write	#sento3

	call	MtxBgn

	gos	getrec <#1, r4, #FB1,>
	tst	20(r1)
	bne	700$
	tst	22(r1)
	beq	800$
700$:	push	r1
	mov	#FB2, r0
	add	#20, r1
	call	fystxt
	pop	r1
	tst	r0			; Deleted text ?
	beq	800$
	push	r1
	gos	getrec <#2, r0, #FB2,>	; Get TEXT node
	bic	#10, 14(r1)		; Remove the no-GC bit
	gos	put <#2,  ,#FB2>	; Put it.
	pop	r1
800$:	pop	20(r1)			; Get text #
	pop	22(r1)
	gos	put <#1, ,#FB1>

	call	MtxEnd

	tst	(pc)+
900$:	sec
	pop	<r0, r4, r3, r2, r1>
	rts	pc
	
;999$:
;	push	r0
;	mov	MaxLin, r0
;	bpt
;	pop	r0
;	rts	pc

; Change presentation of...
;
oChPrs:	
	mov	#2, r0	
	cmp	Level, r0
	bhis	10$
	mov	Me, r0
	br	40$
10$:	call	fixlst
	bcs	90$
	mov	found(r0), r1
	call	GetAdr
	mov	r1, r2
	bit	#AbsPrv!AdmPrv, KSW
	bne	30$
	cmp	Me, (r2)
	beq	30$
	cmp	rPri1(r2), #2	; Meeting
	beq	20$
15$:	write	#DHiR
	br	90$
20$:	gos	getrec <#1, rArg(r2), #FB1, #UnLock>
	cmp	Me, 10(r1)
	bne	15$
30$:	mov	(r2), r0
40$:	call	oMkPrs
90$:	rts	pc


Text	NopMet,	<"Det finns inget m|te f|r presentationer."<cr><lf><cr><lf>>
text	PresOf,	<"[rende: Presentation av ">

	.end