.title	STATUS

	.includ	'b:global'

	sect	code

oSTAT:	cmp	#2,Level
	ble	10$
	mov	Me,r0
	mov	#GRPLST,r1
	call	findcm
	mov	r0,r4
	beq	11$
	sub	#rStr,r4
	br	15$	

10$:	mov	#2,r0
	call	fixlst	
	bcc	12$
11$:	jmp	10000$
12$:	bis	#UtmOn,KSW
	mov	Found(r0),r1
	call	GetAdr
	mov	r1, r4
	cmp	#-2,(r4)
	bne	15$
	Jmp	700$
15$:	Write	#Namnk
	mov	r4,r1
	add	#rStr,r1
	call	STROUT
	call	pcrlf
	Write	#Nrk
	cmp	#4,rPri1(r4)
	bne	17$
	jmp	2000$
17$:	Gos	Getrec, <#1, rArg(r4), #FB1, #Unlock>
	mov	r1,r5
	cmp	#3,(r5)
	bhi	30$
	blo	20$
	Write	#Per
	mov	#-27.,r0
	br	40$
	
20$:	Write	#Met
	mov	#-29.,r0
	br	40$

30$:	Write	#NePe			; N{tPerson
	mov	#-24., r0

40$:	mov	6(r5),r1
	call	deco16
	Write	#SkTi
	mov	r5,r1
	add	#10.,r1
	call	prtdat
	call	pcrlf
	Write	#OBJk
	mov	rArg(r4),r1
	mov	#-34.,r0
	call	deco16
	tstb	160(r5)			; Internet addres
	beq	44$
	Write	#InNaTe
	mov	r5, r1
	add	#160, r1
	call	strout
44$:	call	pcrlf
	cmp	#3, (r5)
	beq	48$
	blo	45$

	jmp	600$			; N{tPerson

45$:	jmp	200$			; M|te

48$:	Write	#PPNk			; Person
	clr	r1
	clr	r0
	clr	out
	bisb	41(r5),r1
	call	deco16
	mov	#',,r0
	call	ttyout
	clr	r0
	clr	r1
	bisb	40(r5),r1
	call	deco16
	mov	#'),r0
	call	ttyout
	mov	#47.,r0
	sub	out,r0
	mov	#SeIn,r1
	call	strouf
	mov	r5,r1
	add	#56.,r1
50$:	call	prtdat
60$:	Write	#NrMe
	mov	24(r5),r1
	mov	r1,@#Tmp+2
	mov	#-29.,r0
	call	deco16
	Write	#NrMark
	mov	74(r5),r1
	clr	r0
	call	deco16
	Write	#NrLet
	mov	rHigh(r4),r1
	mov	#-29.,r0
	call	deco16
	Write	#OBR
	mov	rHigh(r4),r1
	sub	102(r5),r1
	clr	r0
	call	deco16
	Write	#NrALet
	mov	154(r5), r1
	mov	#-29., r0
	call	deco16
	mov	152(r5), r0
	beq	6005$
	Write	#MaxAB
	mov	r0, r1
	clr	r0
	call	deco16
6005$:	clr	Out
	Write	#TTYTXT
	mov	114(r5), r0
	bne	601$
	Write	#Sakn
	br	6021$
601$:	call	prtnam
6021$:	mov	#61., r0
	sub	Out, r0
	mov	#NrSes,r1
	call	strouf
	mov	112(r5), r1
	clr	r0
	call	deco16
	cmpb	#xSuU,@#mypriv
	bhi	603$
	blo	602$
	cmp	10(r5),@#Me
	bne	603$

602$:	Write	#PRIk
	mov	#PRILST,r1
	clr	r0
	bisb	36(r5),r0
	gos	findcm
	mov	r0,r1
	beq	603$
	mov	#-29.,r0
	call	strouf
	Write	#Stato
	clr	r1
	bisb	37(r5),r1
	clr	r0
	call	deco16

603$:	Write	#Skak
	mov	10(r5),r0
	call	prtnam
	tst	@#Tmp+2
	bne	6031$		
	jmp	69$

6031$:	call	PCR2LF
	bcc	605$
604$:	jmp	9999$
605$:	mov	6(r5),r0
	call	PrtNam
	Write	#MeI
	call	PCR2LF
	bcs	604$
	mov	26(r5),@#Tmp
	clr	fb2-2
	clr	fb3-2
62$:	gos	tstrec,	<#1,Tmp, #FB1>
	bcc	625$
	gos	tryrec, <#1, Tmp, #FB2, #Unlock>
625$:	mov	r1,r4
	mov	#20.,@#Tmp+4
	mov	2(r4),@#Tmp
	add	#10,r4
631$:	mov	(r4)+,r0
	mov	#GRPLST,r1
	gos	findcm
	tst	r0
	beq	67$
	mov	r0,r2
	gos	tryrec,	<#1, rArg-rStr(r0), #FB3, #Unlock>
	mov	r1,r3
	mov	rHigh-rStr(r2),r1		; HIGH
	sub	(r4)+,r1
	tst	(r4)+				; Pool-pointer
	mov	#5,r0
	call	deco16
	Write	#Space
	bit	#xOPN,16(r3)
	beq	63$
	mov	#OPN,r1
	br	64$
63$:	mov	#CLOt,r1
64$:	call	STROUT
	cmp	6(r5),10(r3)
	bne	65$
	mov	#ORGt,r1
	br	651$
65$:	mov	#SPC3,r1
651$:	call	strout
	Write	r2
	call	pcrlf
	bcs	100$
66$:	dec	@#Tmp+2			; Antal medlemmar
	blos	69$
	dec	@#Tmp+4
	bhi	631$
	br	62$

67$:	write	#nonam
	mov	-2(r4), r0
	call	prtnam
	call	pcrlf
	add	#4, r4
	br	66$

69$:	call	PCR2LF
	bcs	100$
	mov	142(r5), r4
	beq	80$
	
	Write	#DisT
	gos	PrtDis	<r4, 144(r5),>
	bcs	100$
	call	pcrlf
	bcs	100$

80$:	mov	#FLGLST,r2
	mov	16(r5),r4
	mov	#-42.,r0
	mov	#on, tmp
	mov	#off, tmp+2
	call	LstSet
	bcs	93$
	mov	r5,r1
	add	#106,r1
	tst	(r1)
	bne	92$
	tst	2(r1)
	beq	100$
92$:	call	pcrlf
	mov	#FB3,r0
	call	cnvlet
	bcc	95$
93$:	jmp	10000$
95$:	mov	r0,r1
	mov	#6,r0
	jmp	Disply
100$:	jmp	9999$

 
200$:	clr	out
	Write	#TYPt, #-10		; M|ten
	bit	#xOPN, 16(r5)
	beq	210$
	mov	#OPN, r1
	br	220$
210$:	mov	#CLOt, r1
220$:	call	strout
	bit	#xWP, 16(r5)
	beq	230$
	Write	#SkSt
230$:	mov	#56., r0
	sub	Out, r0
	mov	#DistTx, r1
	call	strouf
	mov	#LocTx, r1
	bit	#xExDs, 16(r5)
	beq	232$
	mov	#ExtTx, r1
232$:	call	strout
	call	pcrlf
	Write	#AMD
	mov	24(r5), r1
	mov	r1, r3
	mov	#-25., r0
	call	deco16
	Write	#AIN
	clr	r0
	mov	rHigh(r4), r1
	call	deco16
	call	pcrlf
	Write	#AAIN
	mov	154(r5), r1
	mov	#-25., r0
	call	deco16
	mov	152(r5), r0
	beq	235$
	Write	#MAXAI
	mov	r0, r1
	clr	r0
	call	deco16
235$:	Write	#ORGAN
	mov	10(r5),r0
	beq	240$
	call	prtnam
	br	245$
240$:	Write	#ING
245$:	tst	r3
	beq	500$
	call	PCR2LF
	mov	r4, r1
	add	#rStr, r1
	call	strout
	Write	#HFM
	mov	26(r5), r2
	clr	fb2-2
250$:	gos	tstrec, <#1, r2, #FB1>
	bcc	260$
	gos	tryrec, <#1, r2, #FB2, #Unlock>
260$:	mov	#61.,r4
	mov	2(r1),r2
	add	#6,r1
270$:	mov	(r1)+,r0
	call	prtnam
	call	pcrlf
	bcs	510$
	dec	r3
	blos	300$
	sob	r4,270$
	br	250$

300$:	call	pcrlf
	bcs	510$
	mov	142(r5), r4
	beq	510$
	
	Write	#DisT
	gos	PrtDis	<r4, 144(r5),>
	bcs	510$

500$:	call	pcrlf
510$:	jmp	9999$

600$:	clr	Out		 	; N[TPERSON
	Write	#StatT
	mov	16(r5), r3
	
	bit	#xNWP, r3
	beq	607$
	Write	#SKRS
	mov	#40, r0
	call	ttyout
607$:	bit	#xNCl, r3
	bne	610$
	mov	#OPN, r1
	br	615$
610$:	mov	#CLOt, r1
615$:	call	strout
	mov	#56., r0
	sub	Out, r0
	mov	#AIN, r1
	call	strouf
	clr	r0
	mov	rHigh(r4),r1
	call	deco16
	call	pcrlf
	Write	#AAIN
	mov	154(r5), r1
	mov	#-25., r0
	call	deco16
	mov	152(r5), r0
	beq	620$
	Write	#MAXAI
	mov	r0, r1
	clr	r0
	call	deco16
620$:	call	pcrlf
	Write	#AIT
	mov	100(r5), r1
	mov	#-17., r0
	call	deco16
	Write	#NetIdT
	mov	36(r5), r1
	clr	r0
	call	deco16
	Write	#ORGAN
	mov	10(r5),r0
	beq	640$
	call	prtnam
	br	660$
640$:	Write	#ING

660$:	call	pcr2lf
690$:	jmp	9999$

700$:	cmp	#3,level		; TERMINAL
	bgt	710$
		
710$:	mov	#4,r0
	call	GetNum
	mov	r1, FB1
	mov	r0, FB1+2
	mov	#FB1,r0
	mov	r0, r1
	call	CnvLet
	bcs	720$
	mov	r0, r4
	gos	getrec, <#2, r4, #FB1, #Unlock>
	call	AccLet
	bcc	730$
	Write	#DHIR
720$:	jmp	10000$
730$:	mov	r1,r5	
	Write	#Nrk
	Write	#Txt
	mov	r5,r1
	tst	(r1)+
	mov	#-29.,r0
	call	deco32
	Write	#SkTi
	mov	r5,r1
	add	#6,r1
	call	prtdat
735$:	call	pcrlf
	bcs	720$
	Write	#OBJk
	mov	#-42,r0
	mov	r4,r1
	call	deco16
	Write	#Stato
	clr	r0
	mov	14(r5),r1
	call	deco16
	Write	#Skak, #-15
	mov	12(r5),r0
	call	prtnam
	bit	#1, 14(r5)
	beq	740$
	call	pcrlf
740$:	clr	FB2-2
	mov	r5, r3
750$:	Write	#Mottk
	mov	16(r3),r0
	clr	out
	call	prtnam	
	bcs	900$
	mov	36(r3), r2
	beq	800$
	mov	#50., r0
	sub	out, r0
	mov	#Txt, r1
	call	strouf
	mov	r3, r1
	tst	(r1)+
	clr	r0
	call	deco32
	cmp	r2, r4			; End detected?
	beq	800$			; Yes!
	gos	TryRec,	<#2, r2, #FB2, #Unlock>
	mov	r1, r3
	br	750$
	
800$:	bit	#xEXT, 14(r5)
	beq	820$
	Write	#NetHdT
	bcs	9999$
	mov	r5, r1
	gos	DspHdr,	<#2>		; Show ALL headers.

820$:	call	pcrlf
900$:	br	9999$

2000$:	Write	#Ter
	mov	(r4), r1
	clr	r0
	call	deco16
	Write	#Skak
	mov	(r4), r1
	cmp	#-1, r1
	bne	2010$
	Write	#SpecT
	mov	rHigh(r4), r4
	br	2200$

2010$:	Gos	GetRec,	<#4, r1, #FB1, #Unlock>
	mov	r1, r5
	mov	2(r5), r0
	call	PrtNam
	call	pcrlf
	mov	r5, r4
	add	#26, r4
	clr	r0
	Write	#nLin1
	clr	r1
	bisb	(r4)+, r1
	call	deco16
	call	pcrlf
	Write	#nCol1
	clr	r1
	bisb	(r4)+, r1
	call	deco16
	mov	(r4)+, r3
	call	PCR2LF
	mov	#SeqLst, r1
2020$:	call	GetAdr
	call	PrtSeq
	mov	rNxt(r1), r1
	bne	2020$
	mov	4(r5), r4

2200$:	call	PCR2LF
	mov	#TTFLST, r2
	mov	#-40, r0
	mov	#NoT, Tmp
	mov	#YesT, Tmp+2
	call	LstSet
	bcs	9999$

9999$:	call	pcrlf
10000$:	bic	#UtmOn,KSW
	rts	pc


LstSet:	mov	r2, r1
10$:	call	GetAdr
	mov	r1, r2
	add	#rStr, r1
	call	Strouf
	mov	#Tmp, r1
	bit	r4, (r2)
	bne	20$
	tst	(r1)+
20$:	Write	(r1)
	call	pcrlf
	bcs	99$
	mov	rNxt(r2), r1
	bne	10$

99$:	rts	pc

oPrSeq:	push	<r2,r1,r0>
	push	CurSek
	add	#rStr, r1
	mov	#-33., Out
	call	Strout
	mov	Out, r0
	mov	#Kolon, r1
	call	Strouf
	clr	r2
	bisb	(r4)+, r2
	bic	#200, r2
	beq	99$
	dec	r3
	blt	99$
5$:	clr	r0
	bisb	(r4), r0
	bic	#200, r0
	beq	10$
	mov	#TDSLST, r1
	call	FindCm
	mov	r0, r1
	beq	7$
	call	Strout
	br	20$

7$:	bisb	(r4), r0
	bic	#200, r0
10$:	mov	r0, r1
	clr	r0
	call	deco16
20$:	inc	r4
	mov	#40, r0
	call	ttyout
	sob	r2, 5$
	br	100$

99$:	mov	#TDSLST, r1
	call	GetAdr
	add	#rStr, r1
	call	Strout

100$:	call	pcrlf
	pop	r1
	call	Popsek			; Restore last sektion. 
	pop	<r0, r1, r2>
	rts	pc


 ; Av STATUS nyttjade str{ngar

Text	StatT,	<"Status: ">
Text	PVVHS,	<"P} vad vill du ha STATUS">
Text	Nrk,	<"Nummer: ">
Text	DisT,	<"Extern distrubution:"<Cr><Lf><Cr><Lf>>
Text	InNaTe,	<"Internetnamn: ">
Text	OBJk,	<"Objekt: ">
Text	PREs,	<"Presentation: ">
Text 	Per,	<"Person ">
Text	Met,	<"M|te ">
Text	NePe,	<"N{tperson ">
Text	Txt,	<"Text ">
Text	Ter,	<"Terminal ">
Text	SkSt,	<", skrivskyddat">
Text	PPNk,	<"PPN:    (">
Text	SkTi,	<"Skapelsetid:  ">
Text	SeIn,	<"Senast inne:  ">
Text	NrMe,	<<15><12>"Antal m|ten: ">
Text	SeCls,	<<CR><LF>"Sekvens f|r radera sk{rmen: ">
Text	SeErol,	<<CR><LF><LF>"Sekvens f|r radera raden:   ">
Text	NrMark,	<"Antal markerade: ">
Text	MeI,	<" {r med i f|ljande m|ten:"<15><12>"Osett  Typ      Namn">
Text	OBR,	<"Ol{sta brev:     ">
Text	NrLet,	<<CR><LF>"Antal brev:  ">
Text	NrALet,	<<CR><LF>"Aktiva brev: ">
Text	TTYTXT,	<<CR><LF>"Terminaltyp: ">
Text	NrSes,	<"Antal sessioner: ">
Text	MaxAB,	<"Max antal brev:  ">
Text	on,	<"P}">
Text	off,	<"Av">
Text	YesT,	<"Ja">
Text	NoT,	<"Nej">
Text	Kolon,	<":">
Text	AMD,	<"Antal medlemmar: ">
Text	AAIN,	<"Aktiva inl{gg:   ">
Text	AIN,	<"Antal inl{gg: ">
Text	MAXAI,	<"Maximalt antal aktiva: ">
Text	NetIdT,	<"N{tverks-status:       ">
Text	AiT,	<"Antal inkommande texter: ">
Text	HFM,	<" har f|ljande medlemmar:"<15><12><12>>
Text	Prik,	<<15><12>"Privilegier: ">
Text	Skak,	<<15><12>"Skapare: ">
Text	Mottk,	<<15><12>"Mottagare: ">
Text	nonam,	<"*****  ******   ">
Text	NetHdT,	<<CR><LF><LF>"N{tverks parametrar: "<Cr><Lf><Lf>>
Text	DistTx,	<"Distribution: ">
Text	LocTx,	<"lokal">
Text	ExtTx,	<"extern">

	.even

	.end