.title	UtmFil

	.inclu	"b:global"
	
	sect	code

OpnFil:	clr	r0
	bisb	(r1)+, r0
	call	DoOpen
	dec	UtmFlg
	rts	pc

UtmFil:	
	Repars	#2, #WhtFil
	bcc	10$
	rts	pc

10$:	mov	strs+2, r1		; Pointer to file name 
	mov	strs+4, r0
	sub	r1, r0
	dec	r0

DoOpen:	mov	r1, -(sp)
	call	clrfqb
	mov	#^rKOM, firqb+fqext	; Default extension
	call	clrxrb
	mov	r0, (r1)+
	mov	r0, (r1)+
	mov	(sp)+, (r1)
	.fss
	call	FilErr
	bcs	900$

100$:	mov	#4, r0			; Save filename and so forth
	mov	#firqb+fqppn, r1
	mov	#UtmNam, r2
110$:	mov	(r1)+, (r2)+
	sob	r0, 110$
	mov	firqb+fqdev, UtmDev
	mov	firqb+fqdev, UtmDev+2
	
	movb	#crefq, firqb+fqfun
	movb	#7*2, firqb+fqfil	; Use channel #7
	calfip
	call	FilErr
	bcs	900$

200$:	mov	#FBU, UtmPtr		; Init current pos. pointer.
	mov	#1, UtmBlk		; Start with block #1 (surprised?)
	mov	#1, UtmFlg

	clc
900$:	rts	pc

UtmOff:
	push	<r0, r1>
	tst	UtmFlg
	bmi	100$
	dec	UtmFlg
	bpl	100$
	mov	UtmPtr, r1
	cmp	r1, #FBU
	beq	20$

	mov	#EOFBU, r0
	sub	r1, r0
10$:	clrb	(r1)+
	sob	r0, 10$
	gos	put <#7, UtmBlk, #FBU>	

20$:	call	clrfqb
	movb	#7*2, firqb+fqfil
	calfip				; Close the file

100$:	pop	<r1, r0>
	rts	pc
 	
	sect	texts

Text	WhtFil,	<"Till vilken fil ">
	
	.even

	.end