.TITLE	SRDTRP
	.IDENT	-6.3-		; 01-JUN-83
	.ENABL	LC
;+
;	SRDTRP - Error handler routine
;
; Broken out as subroutine by ??? on ???
;
; Modifications:
;
;	V6.2 Bob Denny  13-Jul-82	Lower case error messages, minor
;			;RBD001		message changes.
;					Exit with status on '11M
;
;	V6.3 Carl Friedberg 1-June-83	PSECTS  ;CEF001
;-
	.MCALL	QIO$S,WTSE$S,CALLR,CLOSE$,PUT$S
	.MACRO	MESG$	STRING
	.ASCIZ	\STRING\
	.ENDM
	.PSECT	SRDATA,D,RW,LCL,CON,REL                                         ;CEF001
MESG:	.ASCII	/SRD -- */
SERV:	.BLKB	4
	.ASCII	/* /
MES1:	.BLKB	80.
	.EVEN
	.PSECT	SRDCOD,I,RO,LCL,CON,REL                                         ;CEF001
TRAP0::
	MOV	R0,R0SAV
	MOV	R1,R1SAV
	MOV	R2,R2SAV
	.IF DF R$$11M                                                           ;RBD001
	MOV	#EX$ERR,X$STAT		; ASSUME "ERROR" STATUS                 ;RBD001
	.ENDC                                                                   ;RBD001
	MOV	#SERV,R1	;POINT AT SEVERITY INDICATOR
	MOV	#"DI,(R1)+	;ASSUME DIAGNOSTIC
	MOV	#"AG,(R1)	;
	ASRB	1(SP)		;IS THIS FATAL OR DIAGNOSTIC?
	BCS	10$		;BR IF DIAGNOSTIC
	.IF DF R$$11M                                                           ;RBD001
	MOV	#EX$SEV,X$STAT		; ERROR IS SEVERE, FATAL                ;RBD001
	.ENDC                                                                   ;RBD001
	MOV	#"TL,(R1)	;SET FATAL HEADER
	MOV	#"FA,-(R1)	;
	MOV	#LSTNX$,2(SP)	;FIX UP RETURN
10$:
	ADD	#ERRTAB,(SP)	;COMPUTE MESSAGE ADDRESS
	MOV	@(SP)+,R1	;GET DESCRIPTOR
	MOV	#MES1,R2	;START OF VARIABLE AREA
20$:	MOVB	(R1)+,(R2)+	;FILL OUT MESSAGE
	BNE	20$		;THE WHOLE THING
	MOV	#MESG,R1	;START OF MESSAGE
	SUB	R1,R2		;R2 GETS LENGTH
40$:	QIO$S	#IO.WVB,#TTYLUN,#17,,,,<R1,R2,#40>
	BCC	50$		;BR IF A-OK
	CALL	ALERR		;DIAGNOSE ERR
	BR	40$		;RETURN IF NO POOL-TRY AGAIN
50$:	WTSE$S	#17		;WAIT FOR I-O TO STOP
	BIS	#FLFL,FLAGS$	;MARK SOMETHING GONE OUT
;
; PUT IT ALSO ON THE LISTING FILE
	BIT	#OUTFSW,FLAGS$		; ONLY IF ONE WAS SPECIFIED
	BEQ	70$
	MOV	#LSTFDB,R0
	TST	F.BDB(R0)		; LISTING FILE OPEN ?
	BEQ	70$			; BR IF NO
	PUT$S	,R1,R2
	MOV	#LINBUF,F.NRBD+2(R0)
70$:	MOV	R0SAV,R0
	MOV	R1SAV,R1
	MOV	R2SAV,R2
	RTT			;RETURN CONTROL
;
	.PSECT	SRDATA,D,RW,LCL,CON,REL                                         ;CEF001
R0SAV:	+0
R1SAV:	+0
R2SAV:	+0
;
;
	.PSECT	MSGTBL,D,RO,LCL,CON,REL                                         ;CEF001
ERRTAB::.WORD	999$
	.WORD	1$, 2$, 3$, 4$, 5$, 6$, 7$
	.WORD	10$,11$,12$,13$,14$,15$,16$,17$
	.WORD	20$,21$,22$,23$,24$,25$,26$,27$,30$
999$:	MESG$	<Directory too big. Doing in pieces. (Rerun with larger INC)>   ;RBD001
1$:	MESG$	<Command read error>                                            ;RBD001
2$:	MESG$	<Command syntax error>                                          ;RBD001
3$:	MESG$	<Error in input spec>                                           ;RBD001
4$:	MESG$	<Error in output spec>                                          ;RBD001
5$:	MESG$	<Directory privilege violation>                                 ;RBD001
6$:	MESG$	<Directory open error>                                          ;RBD001
7$:	MESG$	<Error reading MFD>                                             ;RBD001
10$:	MESG$	<Parse error>                                                   ;RBD001
11$:	MESG$	<Open error>                                                    ;RBD001
12$:	MESG$	<Open error on input>                                           ;RBD001
13$:	MESG$	<Open error on output>                                          ;RBD001
14$:	MESG$	<Directory find error>                                          ;RBD001
15$:	MESG$	<No such file(s)>                                               ;RBD001
16$:	MESG$	<Invalid date format. Enter DD-MMM-YY HH:MM (1-JUN-76 10:30)>   ;RBD001
17$:	MESG$	<Error reading file header for:>                                ;RBD001
20$:	MESG$	<Put error>                                                     ;RBD001
21$:	MESG$	<Get error>                                                     ;RBD001
22$:	MESG$	<Write error>                                                   ;RBD001
23$:	MESG$	<Read error>                                                    ;RBD001
24$:	MESG$	<Error deleting file>                                           ;RBD001
25$:	MESG$	<Directory write-back error>                                    ;RBD001
26$:	MESG$	<File ID-Sequence number mis-match for:>                        ;RBD001
27$:	MESG$	<Write-back cancelled. Can't fit entire directory in core>      ;RBD001
30$:	MESG$	<Header-read privilege violation for:>                          ;RBD001
	.EVEN		;*** MAKE SURE ITS AN EVEN NUMBER ***                   ;**-25
	.END