.title	rfs 	Return file information
	.ident	"V02.00"
;+
; Index		Return file information
;
; Usage
;
;	rfs(fsb, fsb_size)
;	char *fsb;		/* Address of fsb */
;	int fsb_size;		/* Size of fsb */
;
; Description
;
;	rfs() allows the user to obtain information about a file. The user
;	must pass the address of a fsb and fill in the file name information
;	then issue the rfs() call. The fsb will be filled in with the full
;	file specification information. rfs() returns a 0 on an error and
;	and a 1 on success.
;
;-
; Edit History
; V02.00 19-Oct-82 TTC		Rework of old CS library
;

	.MCALL	FSDEF$
	FSDEF$

	.psect	c$code

rfs::	mov	#FS.RFS,fsqio+q.iofn	; Function: FS.RFS
	mov	#fsqio+q.iopl,r0	; r0 -> qio param list for prmclr
	call	prmclr			; Clear parameter list
	mov	C$PMTR+0(r5),fsqio+q.iopl+2	; Parameter #2: Address of fsb
	mov	C$PMTR+2(r5),fsqio+q.iopl+4	; Parameter #3: Size of fsb
	mov	#fsqio,r0		; r0 must = qio for xqiow
	call	.xqiow			; execute qiow
	mov	#1,r0			; Assume success
	cmp	$dsw,#is.suc		; How'd it go
	blo	10$			; Not so good
	cmpb	f.iosb,#is.suc
	beq	20$
10$:	clr	r0			; Branch here if error, r0 = 0
20$:	return
	.end