.TITLE 	SETFIX	SETUP FO COPY
;
; THIS ROUTINE SETS UP FILES FOR I/O.
; IN THIS VERSION, THE FILESPECS ARE FIXED
;
; ROUTINE RETURNS C-BIT SET IF ERROR.
;
;	The following programs are used in the RT-11 User and RT-11
;	Programmer self paced instruction courses for RT-11 V4.They are also
;	similar to programs used in the Programming with RT-11 series for
;	RT-11 V5.0 or later. The name of the files are as specified in the
;	self paced course.
;
;	The code is supplied as a service as Digital does not supply these
;	on diskette.
;	Any copyright is the property of Digital Equipment Corporartion
;
;
	.MCALL	.FETCH,.LOOKUP,.ENTER,.PRINT
	.GLOBL	EMTARG
;
INFILE:	.RAD50	/DK/		;COPY FROM DK:TRAN1.XYZ
	.RAD50	/TRAN1/
	.RAD50	/XYZ/
OUTFIL:	.RAD50	/DK/		;TO DK:TRAN2/XYZ
	.RAD50	/TRAN2/
	.RAD50	/XYZ/
LIMITS: .LIMIT			;GENERATES TWO WORDS, SECOND IS
				;FIRST FREE ADDRESS ABOVE PROGRAM
ANNCE:	.ASCIZ	/PROGRAM COPIES TRAN1.XYZ TO TRAN2.XYZ/
FCH1MS:	.ASCIZ	/ERROR ON FETCH OF OUPUT HANDLER/
FCH2MS:	.ASCIZ	/ERROR ON FETCH OF INPUT HANDLER/
LKPMES:	.ASCIZ	/ERROR ON LOOKUP OF INPUT FILE/
ENTMES:	.ASCIZ	/ERROR ON CREATION OF OUPUT FILE/
	.EVEN
;
;
SETUP::	MOV	R1,-(SP)
	.PRINT	#ANNCE		;ANNOUNCE PROGRAM
;
; FETCH NEEDED HANDLERS
	.FETCH 	LIMITS+2,#OUTFIL	;GET OUTPUT HANDLER
	BCS	FCH1ER		;ERROR IF FETCH FAILS
	MOV	R0,R1		;PRESERVE ADDRESS FOR NEXT FETCH
	.FETCH	R1,#INFILE	;GET OUTPUT HANDLER.	(NOT NECESSARY
				;IF OUTPUT DEVICE=INPUT DEVICE, BUT
				;IT DOES NO HARM EITHER)
	BCS	FCH2ER
;
; OPEN FILES
	.LOOKUP #EMTARG,#3,#INFILE	;FIND INPUT FILE
	BCS	LKPERR
	MOV	R0,R1		;PRESERVE LENGTH OF INPUT FILE
	.ENTER	#EMTARG,#0,#OUTFIL	;CREATE OUTPUT FILE
	BCC	DONE		;RETURN IF NO ERROR
;
; ERROR ROUTINES
;
; CONTROL PASSES HERE IF ENTER FAILS
	.PRINT 	#ENTMES
	BR	ERDONE
LKPERR:	.PRINT	#LKPMES	
	BR	ERDONE
FCH2ER:	.PRINT	#FCH2MS
	BR	ERDONE
FCH1ER:	.PRINT	#FCH1MS
ERDONE:	SEC			;COMMON EXIT FOR ERRORS
DONE:	MOV	(SP)+,R1	;RESTORE R1 (LEAVES C-BIT UNTOUCHED)
	RETURN
	.END