$!
$! BATCH.COM
$!
$!	Submit an indirect command file for Batch
$!
$!	BATCH FOO	== SUBMIT FOO.COM
$!	BATCH @FOO	== SUBMIT FOO.COM
$!	BATCH $FOO	== execute FOO as a command.
$!
$!
$!	Note disk and directory from which submitted
$!
$ HERESYM := 'F$LOGICAL("SYS$DISK")''F$DIRECTORY()'
$!
$!	Note person submitting
$!
$ WHOSYM := 'F$PROCESS()
$!
$!	Create the file to be submitted
$!
$ OPEN/WRITE TMP SYS$LOGIN:QSUBMIT.TMP
$!
$!	Prevent the log file from being spooled to printer
$!
$ WRITE TMP "$ ASSIGN NL SYS$PRINT"
$!
$ WRITE TMP "$ SET NOVERIFY"
$ WRITE TMP "$ SET WORKING/LIMIT=1000"
$ WRITE TMP "$ ON ERROR THEN $GOTO FINIS"
$!
$!	Set default to submitting directory
$!
$ WRITE TMP "$ SET DEF ''HERESYM'"
$!
$ IF "''F$EXTRACT(0, 1, P1)'" .EQS. "@" THEN P1 := "$ "  'P1'
$ IF "''F$EXTRACT(0, 1, P1)'" .NES. "$" THEN P1 := "$ @" 'P1'
$ WRITE TMP "''P1' ''P2' ''P3' ''P4' ''P5' ''P6' ''P7' ''P8 "
$!
$ WRITE TMP "$FINIS:"
$!
$!	Send mail to submitter announcing completion
$!
$ WRITE TMP "$ MAIL"
$ WRITE TMP "SEND"
$ WRITE TMP "''WHOSYM'"
$ T := 'F$LOGICAL("SYS$LOGIN")'
$ WRITE TMP "Batch Command Completed, log in ''T'QSUBMIT.LOG"
$ P1 := "''F$EXTRACT(1, 9999, P1)'"
$ WRITE TMP "''P1' ''P2' ''P3' ''P4' ''P5' ''P6' ''P7' ''P8'"
$!
$!	Close created command file and submit to batch
$!	The log will be named QSUBMIT.LOG in home directory
$!
$ CLOSE TMP
$ SUBMIT SYS$LOGIN:QSUBMIT.TMP