:	awkWARD Accounting Made Easy
:	[C] Copyright PC Research, Inc. 1985
:
: prbook book [YR=yy]: print checkbook [for year yy]
: FILE FORMAT
: CLEAR	DATE	CHECK	AMOUNT	ACCOUNT	COMMENT
BOOK=$1;
if [ ! -f "$BOOK" ]
then
	echo "usage: prbook book [YR=yy]"
	exit 1;
fi
shift; OPTS="$*"
awk '
{
	if ($1 == "#")
		continue;
	if ( $1 == "H" )
	{
		h = "Check Transactions for " substr($0, 3);
		continue;
	}
	yr=split($2, date, "/");
	if (YR != "" && date[yr] != YR)
		{ if ($5 == "+") cur += $4; else cur -= $4; continue; }
	l = substr($0, index($0, $6));
	if ( (ln % 58) == 0)
	{
		if (ln != 0) printf "\n\n"
		printf "\n\n%s, Page %d\n\n", h, ln/58+1
		printf "C CHEK   DATE   %-35s  PAYMENT  DEPOSIT  BALANCE\n",\
			"DESCRIPTION"
		printf "- ---- -------- %-35s  -------  -------  -------\n",\
			"-----------------------------------"
	}
	if ($5 == "+") 
	{
		cur += $4;
		printf "%s %4s %8s %-35s %8s %8.2f %8.2f\n",$1,$3,$2,l,"",$4,cur
	}
	else
	{
		cur -= $4;
		printf "%s %4s %8s %-35s %8.2f %8s %8.2f\n",$1,$3,$2,l,$4,"",cur
	}
	++ln
}' $OPTS $BOOK
