! squtes.tes - squ the  *.tes files that need to be compiled		!
!squtes.tec!
0^X				! either case match			!
@en%*.tes%			! find all the *.tes files		!
<				! loop					!
  :@en%%;			!   get next filespec, exit if no more	!
  g*				!   insert the filespec into the buffer	!
  ^SC				!   baqckup in front of this filespce	!
  @I%teco -msqu %		!   insert teco mung squ on file	!
  @FS%.TES%,%			!   replace extension with ","		!
  3,@:EN%%\			!   get the date and insert it into buf !
  @I%,%				!   insert another ","			!
  2,:@EN%%\			!   get the time and insert it into buf !
  @I%
%				!   and insert <cr><lf>			!
>				!   end loop				!
! at this time I have a batch file with date and time of .tes files	!
@en%*.tec%			! find all the *.tec files		!
<				! loop					!
  :@en%%;			!   get next filespec, exit if no more	!
  ZJ				!   end of buffer			!
  G*				!   insert the filespec into the buffer	!
  ^Y-4XF			!   put file name sans .tec in F.str	!
  ^SD				!   filespec				!
  J				!   front of buffer			!
  :@S~ ^EQF,~"S			!   if "<sp>filespec," found		!
    3,:@EN%%-(\)UD		!   D=date(tec)-date(tes)		!
    QD"L F< '			!   iif date(tec)<date(tes) continue	!
    QD"E			!   if date(tec)=date(tes)		!
      C				!     advance over ","			!
      2,:@EN%%-(\)"L F< '	!     iif time(tec)<time(tes) continue	!
    '				!   endif date(tec)=date(tes)		!
    0L				!   go to front of line	(tec)>=(tes)	!
    K				!   kill it out				!
  '				!   endif <sp>filespec<sp> found	!
>				! end loop				!
J				! start of buffer			!
<				! loop					!
  :@S%,%;			!   find "," exit if no more		!
  R				!   backup in front of ","		!
  .UF				!   remember front of line		!
  LRR				!   go to end of line			!
  QF,.K				!   kill out the date and time		!
  CC				!   advance over <cr><lf>		!
>				! end loop				!
Z"N				!   if we have something to do		!
  @EW%squtes.bat%		!     make a batch file			!
  EC				!     close out the batch file		!
  @:EG%squtes.bat%		!     chain to the batch file		!
  				! *** Note, :EG can run .bat files but	!
  				!     EG can only run .exe or .com files!
'				!   endif we have something to do	!
@^A%? the *.tes files have dissapeared?
%